run: install-dependencies start-database migrate-database seed-database
    mix phx.server

install-dependencies:
    mix deps.get

migrate-database:
    mix ash.setup

reset-database:
    mix ash.reset

seed-database:
    mix run priv/repo/seeds.exs

start-database:
    docker compose up -d

ci-dev: lint audit test

lint:
    mix format --check-formatted
    mix compile --warnings-as-errors
    mix credo

audit:
    mix sobelow --config
    mix deps.audit
    mix hex.audit

test:
    mix test

format:
    mix format

build-docker-container:
    docker build --tag mitgliederverwaltung .

# This is meant for debugging the container build process only.
run-docker-container: build-docker-container
    podman run -e "SECRET_KEY_BASE=ahK8BeiDaibaige1ahkooS0chie9lo7the7uuzar0eeBeeCh2iereteshee2Oosu" -e='DATABASE_URL=postgres://postgres@localhost:5432/mv_dev' -e='PORT=4040' -e='PHX_HOST=localhost' --network=host mitgliederverwaltung

regen-migrations migration_name:
  #!/bin/bash
  set -euo pipefail
  # Get count of untracked migrations
  N_MIGRATIONS=$(git ls-files --others priv/repo/migrations | wc -l)
  # Rollback untracked migrations
  mix ash_postgres.rollback -n $N_MIGRATIONS
  # Delete untracked migrations and snapshots
  git ls-files --others priv/repo/migrations | xargs rm
  git ls-files --others priv/resource_snapshots | xargs rm
  # Regenerate migrations
  mix ash.codegen --name {{migration_name}}
  # Run migrations if flag
  if echo $* | grep -e "-m" -q; then
    mix ash.migrate
  fi