defmodule MvWeb.MemberLive.FormComponent do
  use MvWeb, :live_component

  @impl true
  def mount(socket) do
    {:ok, property_types} = Mv.Membership.list_property_types()

    initial_properties =
      Enum.map(property_types, fn pt ->
        %{
          "property_type_id" => pt.id,
          "value" => nil
        }
      end)

    {:ok, assign(socket, property_types: property_types, initial_properties: initial_properties)}
  end

  @impl true
  def render(assigns) do
    ~H"""
    <div>
      <.header>
        {@title}
        <:subtitle>Use this form to manage member records and their properties.</:subtitle>
      </.header>

      <.simple_form
        for={@form}
        id="member-form"
        phx-target={@myself}
        phx-change="validate"
        phx-submit="save"
      >
        <.inputs_for :let={f_property} field={@form[:properties]}>
          <% type = Enum.find(@property_types, &(&1.id == f_property[:property_type_id].value)) %>
          <.input field={f_property[:value]} label={type && type.name} />
          <input
            type="hidden"
            name={f_property[:property_type_id].name}
            value={f_property[:property_type_id].value}
          />
        </.inputs_for>

        <:actions>
          <.button phx-disable-with="Saving...">Save Member</.button>
        </:actions>
      </.simple_form>
    </div>
    """
  end

  @impl true
  def update(assigns, socket) do
    {:ok,
     socket
     |> assign(assigns)
     |> assign_form()}
  end

  @impl true
  def handle_event("validate", %{"member" => member_params}, socket) do
    {:noreply, assign(socket, form: AshPhoenix.Form.validate(socket.assigns.form, member_params))}
  end

  def handle_event("save", %{"member" => member_params}, socket) do
    case AshPhoenix.Form.submit(socket.assigns.form, params: member_params) do
      {:ok, member} ->
        notify_parent({:saved, member})

        socket =
          socket
          |> put_flash(:info, "Member #{socket.assigns.form.source.type}d successfully")
          |> push_patch(to: socket.assigns.patch)

        {:noreply, socket}

      {:error, form} ->
        {:noreply, assign(socket, form: form)}
    end
  end

  defp notify_parent(msg), do: send(self(), {__MODULE__, msg})

  defp assign_form(%{assigns: %{member: member}} = socket) do
    form =
      if member do
        {:ok, member} = Ash.load(member, properties: [:property_type])

        is_missing_property = fn i ->
          not Enum.any?(member.properties, fn p ->
            Map.get(i, "property_type_id") == p.property_type_id
          end)
        end

        form =
          AshPhoenix.Form.for_update(
            member,
            :update_member,
            api: Mv.Membership,
            as: "member",
            forms: [auto?: true]
          )

        missing_properties = Enum.filter(socket.assigns[:initial_properties], is_missing_property)

        Enum.reduce(
          missing_properties,
          form,
          &AshPhoenix.Form.add_form(&2, [:properties], params: &1)
        )
      else
        AshPhoenix.Form.for_create(
          Mv.Membership.Member,
          :create_member,
          api: Mv.Membership,
          as: "member",
          params: %{"properties" => socket.assigns[:initial_properties]},
          forms: [auto?: true]
        )
      end

    assign(socket, form: to_form(form))
  end
end