mitgliederverwaltung/test/mv_web/member_live/index_test.exs

defmodule MvWeb.MemberLive.IndexTest do
  use MvWeb.ConnCase, async: true
  import Phoenix.LiveViewTest
  require Ash.Query

  test "shows translated title in German", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    conn = Plug.Test.init_test_session(conn, locale: "de")
    {:ok, _view, html} = live(conn, "/members")
    # Expected German title
    assert html =~ "Mitglieder"
  end

  test "shows translated title in English", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    Gettext.put_locale(MvWeb.Gettext, "en")
    {:ok, _view, html} = live(conn, "/members")
    # Expected English title
    assert html =~ "Members"
  end

  test "shows translated button text in German", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    conn = Plug.Test.init_test_session(conn, locale: "de")
    {:ok, _view, html} = live(conn, "/members/new")
    assert html =~ "Speichern"
  end

  test "shows translated button text in English", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    Gettext.put_locale(MvWeb.Gettext, "en")
    {:ok, _view, html} = live(conn, "/members/new")
    assert html =~ "Save"
  end

  test "shows translated flash message after creating a member in German", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    conn = Plug.Test.init_test_session(conn, locale: "de")
    {:ok, form_view, _html} = live(conn, "/members/new")

    form_data = %{
      "member[first_name]" => "Max",
      "member[last_name]" => "Mustermann",
      "member[email]" => "max@example.com"
    }

    # Submit form and follow the redirect to get the flash message
    {:ok, index_view, _html} =
      form_view
      |> form("#member-form", form_data)
      |> render_submit()
      |> follow_redirect(conn, "/members")

    assert has_element?(index_view, "#flash-group", "Mitglied erstellt erfolgreich")
  end

  test "shows translated flash message after creating a member in English", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    {:ok, form_view, _html} = live(conn, "/members/new")

    form_data = %{
      "member[first_name]" => "Max",
      "member[last_name]" => "Mustermann",
      "member[email]" => "max@example.com"
    }

    # Submit form and follow the redirect to get the flash message
    {:ok, index_view, _html} =
      form_view
      |> form("#member-form", form_data)
      |> render_submit()
      |> follow_redirect(conn, "/members")

    assert has_element?(index_view, "#flash-group", "Member create successfully")
  end

  describe "sorting interaction" do
    test "clicking a column header toggles sort order and updates the URL", %{conn: conn} do
      conn = conn_with_oidc_user(conn)
      {:ok, view, _html} = live(conn, "/members")

      # The component data test ids are built as "<field>"
      # First click – should sort ASC
      view
      |> element("[data-testid='email']")
      |> render_click()

      # The LiveView pushes a patch with the new query params
      assert_patch(view, "/members?sort_field=email&sort_order=asc")

      # Second click – toggles to DESC
      view
      |> element("[data-testid='email']")
      |> render_click()

      assert_patch(view, "/members?sort_field=email&sort_order=desc")
    end
  end

  describe "URL param handling" do
    test "handle_params reads sort query and applies it", %{conn: conn} do
      conn = conn_with_oidc_user(conn)
      url = "/members?sort_field=email&sort_order=desc"

      conn = get(conn, url)

      # The LiveView must have parsed the params and stored them as atoms.
      assert conn.assigns.sort_field == :email
      assert conn.assigns.sort_order == :desc
    end
  end

  test "handle_info(:search_changed) updates assigns with search results", %{conn: conn} do
    conn = conn_with_oidc_user(conn)
    {:ok, view, _html} = live(conn, "/members")

    send(view.pid, {:search_changed, "Friedrich"})

    state = :sys.get_state(view.pid)

    assert state.socket.assigns.query == "Friedrich"
    assert is_list(state.socket.assigns.members)
  end

  test "can delete a member without error", %{conn: conn} do
    # Create a test member first
    {:ok, member} =
      Mv.Membership.create_member(%{
        first_name: "Test",
        last_name: "User",
        email: "test@example.com"
      })

    conn = conn_with_oidc_user(conn)
    {:ok, index_view, _html} = live(conn, "/members")

    # Verify the member is displayed
    assert has_element?(index_view, "#members", "Test User")

    # Click the delete link for this member
    index_view
    |> element("a", "Delete")
    |> render_click()

    # Verify the member is no longer displayed
    refute has_element?(index_view, "#members", "Test User")

    # Verify the member was actually deleted from the database
    assert not (Mv.Membership.Member |> Ash.Query.filter(id == ^member.id) |> Ash.exists?())
  end
end