feat(members,properties): add liveview

lib/mv_web/member_live/form_component.ex

@@ -0,0 +1,127 @@
+defmodule MvWeb.MemberLive.FormComponent do
+  use MvWeb, :live_component
+
+  @impl true
+  def mount(socket) do
+    {:ok, property_types} = Mv.Membership.list_property_types()
+
+    initial_properties =
+      Enum.map(property_types, fn pt ->
+        %{
+          "property_type_id" => pt.id,
+          "value" => nil
+        }
+      end)
+
+    {:ok, assign(socket, property_types: property_types, initial_properties: initial_properties)}
+  end
+
+  @impl true
+  def render(assigns) do
+    ~H"""
+    <div>
+      <.header>
+        {@title}
+        <:subtitle>Use this form to manage member records and their properties.</:subtitle>
+      </.header>
+
+      <.simple_form
+        for={@form}
+        id="member-form"
+        phx-target={@myself}
+        phx-change="validate"
+        phx-submit="save"
+      >
+        <.inputs_for :let={f_property} field={@form[:properties]}>
+          <% type = Enum.find(@property_types, &(&1.id == f_property[:property_type_id].value)) %>
+          <.input field={f_property[:value]} label={type && type.name} />
+          <input
+            type="hidden"
+            name={f_property[:property_type_id].name}
+            value={f_property[:property_type_id].value}
+          />
+        </.inputs_for>
+
+        <:actions>
+          <.button phx-disable-with="Saving...">Save Member</.button>
+        </:actions>
+      </.simple_form>
+    </div>
+    """
+  end
+
+  @impl true
+  def update(assigns, socket) do
+    {:ok,
+     socket
+     |> assign(assigns)
+     |> assign_form()}
+  end
+
+  @impl true
+  def handle_event("validate", %{"member" => member_params}, socket) do
+    {:noreply, assign(socket, form: AshPhoenix.Form.validate(socket.assigns.form, member_params))}
+  end
+
+  def handle_event("save", %{"member" => member_params}, socket) do
+    case AshPhoenix.Form.submit(socket.assigns.form, params: member_params) do
+      {:ok, member} ->
+        notify_parent({:saved, member})
+
+        socket =
+          socket
+          |> put_flash(:info, "Member #{socket.assigns.form.source.type}d successfully")
+          |> push_patch(to: socket.assigns.patch)
+
+        {:noreply, socket}
+
+      {:error, form} ->
+        {:noreply, assign(socket, form: form)}
+    end
+  end
+
+  defp notify_parent(msg), do: send(self(), {__MODULE__, msg})
+
+  defp assign_form(%{assigns: %{member: member}} = socket) do
+    form =
+      if member do
+        {:ok, member} = Ash.load(member, properties: [:property_type])
+
+        existing_properties =
+          member.properties
+          |> Enum.map(& &1.property_type_id)
+
+        is_missing_property = fn i ->
+          not Enum.member?(existing_properties, Map.get(i, "property_type_id"))
+        end
+
+        form =
+          AshPhoenix.Form.for_update(
+            member,
+            :update_member,
+            api: Mv.Membership,
+            as: "member",
+            forms: [auto?: true]
+          )
+
+        missing_properties = Enum.filter(socket.assigns[:initial_properties], is_missing_property)
+
+        Enum.reduce(
+          missing_properties,
+          form,
+          &AshPhoenix.Form.add_form(&2, [:properties], params: &1)
+        )
+      else
+        AshPhoenix.Form.for_create(
+          Mv.Membership.Member,
+          :create_member,
+          api: Mv.Membership,
+          as: "member",
+          params: %{"properties" => socket.assigns[:initial_properties]},
+          forms: [auto?: true]
+        )
+      end
+
+    assign(socket, form: to_form(form))
+  end
+end

lib/mv_web/member_live/index.ex

@@ -0,0 +1,99 @@
+defmodule MvWeb.MemberLive.Index do
+  use MvWeb, :live_view
+
+  @impl true
+  def render(assigns) do
+    ~H"""
+    <.header>
+      Listing Members
+      <:actions>
+        <.link patch={~p"/members/new"}>
+          <.button>New Member</.button>
+        </.link>
+      </:actions>
+    </.header>
+
+    <.table
+      id="members"
+      rows={@streams.members}
+      row_click={fn {_id, member} -> JS.navigate(~p"/members/#{member}") end}
+    >
+      <:col :let={{_id, member}} label="Id">{member.id}</:col>
+
+      <:action :let={{_id, member}}>
+        <div class="sr-only">
+          <.link navigate={~p"/members/#{member}"}>Show</.link>
+        </div>
+
+        <.link patch={~p"/members/#{member}/edit"}>Edit</.link>
+      </:action>
+
+      <:action :let={{id, member}}>
+        <.link
+          phx-click={JS.push("delete", value: %{id: member.id}) |> hide("##{id}")}
+          data-confirm="Are you sure?"
+        >
+          Delete
+        </.link>
+      </:action>
+    </.table>
+
+    <.modal
+      :if={@live_action in [:new, :edit]}
+      id="member-modal"
+      show
+      on_cancel={JS.patch(~p"/members")}
+    >
+      <.live_component
+        module={MvWeb.MemberLive.FormComponent}
+        id={(@member && @member.id) || :new}
+        title={@page_title}
+        action={@live_action}
+        member={@member}
+        patch={~p"/members"}
+      />
+    </.modal>
+    """
+  end
+
+  @impl true
+  def mount(_params, _session, socket) do
+    {:ok, stream(socket, :members, Ash.read!(Mv.Membership.Member))}
+  end
+
+  @impl true
+  def handle_params(params, _url, socket) do
+    {:noreply, apply_action(socket, socket.assigns.live_action, params)}
+  end
+
+  defp apply_action(socket, :edit, %{"id" => id}) do
+    socket
+    |> assign(:page_title, "Edit Member")
+    |> assign(:member, Ash.get!(Mv.Membership.Member, id))
+  end
+
+  defp apply_action(socket, :new, _params) do
+    socket
+    |> assign(:page_title, "New Member")
+    |> assign(:member, nil)
+  end
+
+  defp apply_action(socket, :index, _params) do
+    socket
+    |> assign(:page_title, "Listing Members")
+    |> assign(:member, nil)
+  end
+
+  @impl true
+  def handle_info({MvWeb.MemberLive.FormComponent, {:saved, member}}, socket) do
+    {:noreply, stream_insert(socket, :members, member)}
+  end
+
+  @impl true
+  def handle_event("delete", %{"id" => id}, socket) do
+    member = Ash.get!(Mv.Membership.Member, id)
+    Ash.destroy!(member)
+
+    {:noreply, stream_delete(socket, :members, member)}
+  end
+end

lib/mv_web/member_live/show.ex

@@ -0,0 +1,57 @@
+defmodule MvWeb.MemberLive.Show do
+  use MvWeb, :live_view
+
+  @impl true
+  def render(assigns) do
+    ~H"""
+    <.header>
+      Member {@member.id}
+      <:subtitle>This is a member record from your database.</:subtitle>
+
+      <:actions>
+        <.link patch={~p"/members/#{@member}/show/edit"} phx-click={JS.push_focus()}>
+          <.button>Edit member</.button>
+        </.link>
+      </:actions>
+    </.header>
+
+    <.list>
+      <:item title="Id">{@member.id}</:item>
+    </.list>
+
+    <.back navigate={~p"/members"}>Back to members</.back>
+
+    <.modal
+      :if={@live_action == :edit}
+      id="member-modal"
+      show
+      on_cancel={JS.patch(~p"/members/#{@member}")}
+    >
+      <.live_component
+        module={MvWeb.MemberLive.FormComponent}
+        id={@member.id}
+        title={@page_title}
+        action={@live_action}
+        member={@member}
+        patch={~p"/members/#{@member}"}
+      />
+    </.modal>
+    """
+  end
+
+  @impl true
+  def mount(_params, _session, socket) do
+    {:ok, socket}
+  end
+
+  @impl true
+  def handle_params(%{"id" => id}, _, socket) do
+    {:noreply,
+     socket
+     |> assign(:page_title, page_title(socket.assigns.live_action))
+     |> assign(:member, Ash.get!(Mv.Membership.Member, id))}
+  end
+
+  defp page_title(:show), do: "Show Member"
+  defp page_title(:edit), do: "Edit Member"
+end