mitgliederverwaltung/lib/mv_web/live/datafields_live.ex

defmodule MvWeb.DatafieldsLive do
  @moduledoc """
  LiveView for managing member field visibility/required and custom fields (datafields).

  Renders MemberFieldLive.IndexComponent and CustomFieldLive.IndexComponent.
  Moved from GlobalSettingsLive (Memberdata section) to a dedicated page.
  """
  use MvWeb, :live_view

  alias Mv.Membership

  on_mount {MvWeb.LiveHelpers, :ensure_user_role_loaded}

  @impl true
  def mount(_params, _session, socket) do
    {:ok, settings} = Membership.get_settings()

    {:ok,
     socket
     |> assign(:page_title, gettext("Datafields"))
     |> assign(:settings, settings)
     |> assign(:active_editing_section, nil)
     |> assign(:custom_field_delete_modal_open, false)}
  end

  @impl true
  def handle_event("window_keydown", %{"key" => key}, socket)
      when key in ["Escape", "Esc"] do
    if socket.assigns[:custom_field_delete_modal_open] do
      send_update(MvWeb.CustomFieldLive.IndexComponent,
        id: "custom-fields-component",
        show_delete_modal: false,
        custom_field_to_delete: nil,
        slug_confirmation: ""
      )

      {:noreply,
       socket
       |> assign(:custom_field_delete_modal_open, false)
       |> push_event("focus_restore", %{id: "delete-custom-field-trigger"})}
    else
      {:noreply, socket}
    end
  end

  def handle_event("window_keydown", _params, socket), do: {:noreply, socket}

  @impl true
  def render(assigns) do
    ~H"""
    <Layouts.app flash={@flash} current_user={@current_user} club_name={@settings.club_name}>
      <.header>
        {gettext("Datafields")}
        <:subtitle>
          {gettext(
            "Configure which data you want to save for your members. Define individual datafields."
          )}
        </:subtitle>
      </.header>

      <%!-- Overview: both sections with form_section wrappers; FocusRestore for custom field delete modal --%>
      <div
        :if={@active_editing_section == nil}
        id="datafields-focus-root"
        class="mt-6 space-y-6"
        phx-hook="FocusRestore"
        phx-window-keydown={if @custom_field_delete_modal_open, do: "window_keydown", else: nil}
      >
        <.form_section title={gettext("Personal Data")}>
          <.live_component
            module={MvWeb.MemberFieldLive.IndexComponent}
            id="member-fields-component"
            settings={@settings}
          />
        </.form_section>

        <.form_section title={gettext("Individual Datafields")}>
          <.live_component
            module={MvWeb.CustomFieldLive.IndexComponent}
            id="custom-fields-component"
            actor={@current_user}
          />
        </.form_section>
      </div>

      <%!-- Edit mode: only the active section, no section title/card wrapper --%>
      <div :if={@active_editing_section == :member_fields} class="mt-6">
        <.live_component
          module={MvWeb.MemberFieldLive.IndexComponent}
          id="member-fields-component"
          settings={@settings}
        />
      </div>

      <div
        :if={@active_editing_section == :custom_fields}
        id="datafields-focus-root"
        class="mt-6"
        phx-hook="FocusRestore"
        phx-window-keydown={if @custom_field_delete_modal_open, do: "window_keydown", else: nil}
      >
        <.live_component
          module={MvWeb.CustomFieldLive.IndexComponent}
          id="custom-fields-component"
          actor={@current_user}
        />
      </div>
    </Layouts.app>
    """
  end

  @impl true
  def handle_info({:custom_field_delete_modal_open, open}, socket) do
    {:noreply, assign(socket, :custom_field_delete_modal_open, open)}
  end

  @impl true
  def handle_info({:custom_field_saved, _custom_field, action}, socket) do
    send_update(MvWeb.CustomFieldLive.IndexComponent,
      id: "custom-fields-component",
      show_form: false
    )

    {:noreply,
     socket
     |> assign(:active_editing_section, nil)
     |> put_flash(:success, gettext("Data field %{action} successfully", action: action))}
  end

  @impl true
  def handle_info({:custom_field_deleted, _custom_field}, socket) do
    {:noreply, put_flash(socket, :success, gettext("Data field deleted successfully"))}
  end

  @impl true
  def handle_info({:custom_field_delete_error, error}, socket) do
    {:noreply,
     put_flash(
       socket,
       :error,
       gettext("Failed to delete data field: %{error}", error: inspect(error))
     )}
  end

  @impl true
  def handle_info(:custom_field_slug_mismatch, socket) do
    {:noreply, put_flash(socket, :error, gettext("Slug does not match. Deletion cancelled."))}
  end

  def handle_info({:custom_fields_load_error, _error}, socket) do
    {:noreply,
     put_flash(
       socket,
       :error,
       gettext("Could not load data fields. Please check your permissions.")
     )}
  end

  @impl true
  def handle_info({:editing_section_changed, section}, socket) do
    {:noreply, assign(socket, :active_editing_section, section)}
  end

  # Open delete modal for custom field (triggered from Danger zone in FormComponent)
  @impl true
  def handle_info({:open_delete_modal_for, custom_field}, socket) do
    send_update(MvWeb.CustomFieldLive.IndexComponent,
      id: "custom-fields-component",
      open_delete_for_id: custom_field.id
    )

    {:noreply, socket}
  end

  @impl true
  def handle_info({:member_field_saved, _member_field, action}, socket) do
    {:ok, updated_settings} = Membership.get_settings()

    send_update(MvWeb.MemberFieldLive.IndexComponent,
      id: "member-fields-component",
      show_form: false,
      settings: updated_settings
    )

    {:noreply,
     socket
     |> assign(:settings, updated_settings)
     |> assign(:active_editing_section, nil)
     |> put_flash(:success, gettext("Member field %{action} successfully", action: action))}
  end

  @impl true
  def handle_info({:member_field_visibility_updated}, socket) do
    {:ok, updated_settings} = Membership.get_settings()

    send_update(MvWeb.MemberFieldLive.IndexComponent,
      id: "member-fields-component",
      settings: updated_settings
    )

    {:noreply, assign(socket, :settings, updated_settings)}
  end
end