mitgliederverwaltung/lib/mv_web/member_live/form_component.ex

defmodule MvWeb.MemberLive.FormComponent do
  use MvWeb, :live_component

  @impl true
  def mount(socket) do
    {:ok, property_types} = Mv.Membership.list_property_types()

    initial_properties =
      Enum.map(property_types, fn pt ->
        %{
          "property_type_id" => pt.id,
          "value" => %{
            "type" => pt.value_type,
            "value" => nil,
            "_union_type" => Atom.to_string(pt.value_type)
          }
        }
      end)

    {:ok, assign(socket, property_types: property_types, initial_properties: initial_properties)}
  end

  @impl true
  def render(assigns) do
    ~H"""
    <div>
      <.header>
        {@title}
        <:subtitle>{gettext("Use this form to manage member records and their properties.")}</:subtitle>
      </.header>

      <.simple_form
        for={@form}
        id="member-form"
        phx-target={@myself}
        phx-change="validate"
        phx-submit="save"
      >
        <.input field={@form[:first_name]} label={gettext("First Name")} required />
        <.input field={@form[:last_name]} label={gettext("Last Name")} required />
        <.input field={@form[:email]} label={gettext("Email")} required type="email" />
        <.input field={@form[:birth_date]} label={gettext("Birth Date")} type="date" />
        <.input field={@form[:paid]} label={gettext("Paid")} type="checkbox" />
        <.input field={@form[:phone_number]} label={gettext("Phone Number")} />
        <.input field={@form[:join_date]} label={gettext("Join Date")} type="date" />
        <.input field={@form[:exit_date]} label={gettext("Exit Date")} type="date" />
        <.input field={@form[:notes]} label={gettext("Notes")} />
        <.input field={@form[:city]} label={gettext("City")} />
        <.input field={@form[:street]} label={gettext("Street")} />
        <.input field={@form[:house_number]} label={gettext("House Number")} />
        <.input field={@form[:postal_code]} label={gettext("Postal Code")} />

        <h3 class="mt-8 mb-2 text-lg font-semibold">{gettext("Custom Properties")}</h3>
        <.inputs_for :let={f_property} field={@form[:properties]}>
          <% type = Enum.find(@property_types, &(&1.id == f_property[:property_type_id].value)) %>
          <.inputs_for :let={value_form} field={f_property[:value]}>
            <% input_type =
              cond do
                type && type.value_type == :boolean -> "checkbox"
                type && type.value_type == :date -> :date
                true -> :text
              end %>
            <.input field={value_form[:value]} label={type && type.name} type={input_type} />
          </.inputs_for>
          <input
            type="hidden"
            name={f_property[:property_type_id].name}
            value={f_property[:property_type_id].value}
          />
        </.inputs_for>

        <:actions>
          <.button phx-disable-with={gettext("Saving...")}>{gettext("Save Member")}</.button>
        </:actions>
      </.simple_form>
    </div>
    """
  end

  @impl true
  def update(assigns, socket) do
    {:ok,
     socket
     |> assign(assigns)
     |> assign_form()}
  end

  @impl true
  def handle_event("validate", %{"member" => member_params}, socket) do
    {:noreply, assign(socket, form: AshPhoenix.Form.validate(socket.assigns.form, member_params))}
  end

  def handle_event("save", %{"member" => member_params}, socket) do
    case AshPhoenix.Form.submit(socket.assigns.form, params: member_params) do
      {:ok, member} ->
        notify_parent({:saved, member})

        action =
          case socket.assigns.form.source.type do
            :create -> gettext("create")
            :update -> gettext("update")
            other -> to_string(other)
          end

        socket =
          socket
          |> put_flash(:info, gettext("Mitglied %{action} erfolgreich", action: action))
          |> push_patch(to: socket.assigns.patch)

        {:noreply, socket}

      {:error, form} ->
        {:noreply, assign(socket, form: form)}
    end
  end

  defp notify_parent(msg), do: send(self(), {__MODULE__, msg})

  defp assign_form(%{assigns: %{member: member}} = socket) do
    form =
      if member do
        {:ok, member} = Ash.load(member, properties: [:property_type])

        existing_properties =
          member.properties
          |> Enum.map(& &1.property_type_id)

        is_missing_property = fn i ->
          not Enum.member?(existing_properties, Map.get(i, "property_type_id"))
        end

        params = %{
          "properties" =>
            Enum.map(member.properties, fn prop ->
              %{
                "property_type_id" => prop.property_type_id,
                "value" => %{
                  "_union_type" => Atom.to_string(prop.value.type),
                  "type" => prop.value.type,
                  "value" => prop.value.value
                }
              }
            end)
        }

        form =
          AshPhoenix.Form.for_update(
            member,
            :update_member,
            api: Mv.Membership,
            as: "member",
            params: params,
            forms: [auto?: true]
          )

        missing_properties = Enum.filter(socket.assigns[:initial_properties], is_missing_property)

        Enum.reduce(
          missing_properties,
          form,
          &AshPhoenix.Form.add_form(&2, [:properties], params: &1)
        )
      else
        AshPhoenix.Form.for_create(
          Mv.Membership.Member,
          :create_member,
          api: Mv.Membership,
          as: "member",
          params: %{"properties" => socket.assigns[:initial_properties]},
          forms: [auto?: true]
        )
      end

    assign(socket, form: to_form(form))
  end
end